C05-5.mws

COMPLEX ANALYSIS: Maple Worksheets, 2001
(c) John H. Mathews Russell W. Howell
mathews@fullerton.edu howell@westmont.edu

Complimentary software to accompany the textbook:

COMPLEX ANALYSIS: for Mathematics & Engineering, 4th Ed, 2001, ISBN: 0-7637-1425-9
Jones and Bartlett Publishers, Inc., 40 Tall Pine Drive, Sudbury, MA 01776
Tele. (800) 832-0034; FAX: (508) 443-8000, E-mail: mkt@jbpub.com, http://www.jbpub.com/


CHAPTER 5 ELEMENTARY FUNCTIONS

Section 5.5 Inverse Trigonometric and Hyperbolic Functions

We expressed the trigonometric and hyperbolic functions in Section 5.4 in terms of the exponential function. In this section we look at their inverses. When we solve equations such as w = sin(z) for z , we will obtain formulas that involve the logarithm. Since trigonometric and hyperbolic functions are all periodic, they are many-to-one, hence their inverses are necessarily multivalued. The formulas for the inverse trigonometric functions are given by

arcsin(z) = -i*log(i*z+sqrt(1-z^2)) ,

arccos(z) = -i*log(z+i*sqrt(1-z^2)) , and

arctan(z) = i/2 log((i+z)/(i-z)) .

The derivatives of any branch of the functions above can be found by use of the chain rule:

arcsin(z) = 1/sqrt(1-z^2) ,

arccos(z) = 1/sqrt(1-z^2) , and

arctan(z) = 1/(1+z^2) .

Load Maple's "conformal mapping" procedure.
Make sure this is done only ONCE during a Maple session.

> with(plots):


Example 5.11, Page 196. Find the value of arcsin(sqrt(2)) .

> w:='w': z:='z': Z:='Z':
Z := sqrt(2):
`z ` = z;
w := -I*log(I*Z + (1-Z^2)^(1/2)):
-I*log(I*z + (1-z^2)^(1/2)) = w;
w := evalc(w):
-I*log(I*z + (1-z^2)^(1/2)) = w; ` `;
w := arcsin(Z):
`arcsin(z) ` = w;
w := evalc(w):
`arcsin(z) ` = w;

`z ` = z

-I*ln(I*z+sqrt(1-z^2)) = -I*ln(I*sqrt(2)+I)

-I*ln(I*z+sqrt(1-z^2)) = 1/2*Pi-I*ln(1+sqrt(2))

` `

`arcsin(z) ` = arcsin(sqrt(2))

`arcsin(z) ` = 1/2*Pi-I*ln(1+sqrt(2))

Example 5.13, Page 198. Find the value of arctanh(1+2*i) .

> w:='w': z:='z': Z:='Z':
Z := 1 + I*2:
`z ` = Z;
w := 1/2*log((1+Z)/(1-Z)):
log((1+z)/(1-z))/2 = w;
w := evalc(w):
log((1+z)/(1-z))/2 = w; ` `;
w := arctanh(Z):
`arctan(z) ` = w;
w := evalc(w):
`arctanh(z) ` = w;

`z ` = 1+2*I

1/2*ln((1+z)/(1-z)) = 1/2*ln(-1+I)

1/2*ln((1+z)/(1-z)) = 1/4*ln(2)+3/8*I*Pi

` `

`arctan(z) ` = arctanh(1+2*I)

`arctanh(z) ` = 1/4*ln(2)+3/8*I*Pi

The Inverse Sine

Formula: arcsin(z) = -i*Log(i*z+sqrt(1-z^2)) ,
Maple can "almost" derive this formula. Can you tell the difference ?

> w:='w': W:='W': z:='z':
eqn := z = sin(w): eqn;
eqn := z = (exp(I*w)-exp(-I*w))/(2*I): eqn;
eqn := eqn*exp(I*w): eqn;
eqn := expand(eqn): eqn;
`Substitute:`;
W = exp(I*w);
eqn := subs(exp(I*w)= W, eqn): eqn;
solset := solve(eqn, W):
eqn := W = expand(solset[2]): eqn;
eqn := I*w = log(expand(solset[2])): eqn;
eqn := w = -I*log(expand(solset[2])): eqn;
w = arcsin(z);

z = sin(w)

z = -1/2*I*(exp(I*w)-exp(-I*w))

exp(I*w)*z = -1/2*I*exp(I*w)*(exp(I*w)-exp(-I*w))

exp(I*w)*z = -1/2*I*exp(I*w)^2+1/2*I

`Substitute:`

W = exp(I*w)

W*z = -1/2*I*W^2+1/2*I

W = I*z+I*sqrt(z^2-1)

I*w = ln(I*z+I*sqrt(z^2-1))

w = -I*ln(I*z+I*sqrt(z^2-1))

w = arcsin(z)

Formula arcsin(z) = -i*Log(i*z+sqrt(1-z^2)) , is correct, we can verify this graphically.
(At least for values of z in the upper half plane 0 < Im(z) .)

> f:='f': z:='z':
f := z -> - I*log(I*z + sqrt(1 - z^2)):
`f(z) ` = f(z);
conformal(f(z), z = -5+I*0.0001..5+I*10,
title=`w = - I*log(I*z + sqrt(1 - z^2))`,
grid=[11,11], numxy=[50,50],
scaling=constrained,
labels=[`u`,`v `],
view=[-1.7..1.7,0..3.4]);

`f(z) ` = -I*ln(I*z+sqrt(1-z^2))

[Maple Plot]

> `f(z) = arcsin(z)`;
conformal(arcsin(z), z = -5+I*0.0001..5+I*10,
title=`w = arcsin(z)`,
grid=[11,11], numxy=[50,50],
scaling=constrained,
labels=[`u`,`v `],
view=[-1.7..1.7,0..3.4]);

`f(z) = arcsin(z)`

[Maple Plot]

REMARK. If you mess around with the square root it will be wrong. The portion that is supposed be
in the first quadrant appears symmetrically through z = pi/2 in the fourth quadrant.

> f:'f':
f := z -> - I*log(I*z + I*sqrt(z^2 - 1)):
`f(z) ` = f(z);
conformal(f(z), z = -5+I*0.0001..5+I*10,
title=`w = - I*log(I*z + I*sqrt(z^2 - 1))`,
grid=[11,11], numxy=[50,50],
scaling=constrained,
labels=[`u`,`v`]);

`f(z) ` = -I*ln(I*z+I*sqrt(z^2-1))

[Maple Plot]

The Inverse Cosine

Formula arccos(z) = -i*Log(z+i*sqrt(1-z^2)) is correct, we can verify this graphically.
(At least for values of z in the upper half plane Im(z) > 0.)

> f:='f': z:='z':
f := z -> - I*log(z + I*sqrt(1 - z^2)):
`f(z) ` = f(z);
conformal(f(z), z = -Pi/2+I*0.0001..Pi/2+I*3,
title=`w = - I*log(z + I*sqrt(1 - z^2))`,
grid=[11,11], numxy=[50,50],
scaling=constrained,
labels=[` u`,`v `],
view=[0..3.15,-2..0]);

`f(z) ` = -I*ln(z+I*sqrt(1-z^2))

[Maple Plot]

> `f(z) = arccos(z)`;
conformal(arccos(z), z = -Pi/2+I*0.0001..Pi/2+I*3,
title=`w = arccos(z)`,
grid=[11,11], numxy=[50,50],
scaling=constrained,
labels=[` u`,`v `],
view=[0..3.15,-2..0]);

`f(z) = arccos(z)`

[Maple Plot]

REMARK. If you mess around with the square root it will be wrong.

> f:='f': z:='z':
f := z -> - I*log(z + sqrt(z^2 - 1)):
`f(z) ` = f(z);
conformal(f(z), z = -Pi/2+I*0.0001..Pi/2+I*3,
title=`w = - I*log(z + sqrt(z^2 - 1))`,
grid=[20,20], numxy=[100,100],
scaling=constrained,
labels=[`u`,`v`]);

`f(z) ` = -I*ln(z+sqrt(z^2-1))

[Maple Plot]

The Inverse Tangent
Formula arctan(z) = i/2*Log((i+z)/(i-z)) is correct, we can verify this graphically.
(At least for values of z in the upper half plane 0 < Im(z) .)

> f:='f': z:='z':
f := z -> I/2 *log((I+z)/(I-z)):
`f(z) ` = f(z);
conformal(f(z), z = 0.0001+I*0.0001..1.5706+I*3,
title=`w = I/2 *log((I+z)/(I-z))`,
grid=[11,11], numxy=[100,100],
scaling=constrained,
labels=[` u`,`v `],
view=[0..2,0..1.6]);

`f(z) ` = 1/2*I*ln((I+z)/(I-z))

[Maple Plot]

> `f(z) = arctan(z)`;
conformal(arctan(z), z = 0.0001+I*0.0001..1.5706+I*3,
title=`w = arctan(z)`,
grid=[20,20], numxy=[100,100],
scaling=constrained,
labels=[` u`,`v `],
view=[0..2,0..1.6]);

`f(z) = arctan(z)`

[Maple Plot]

The Inverse Hyperbolic Sine

Formula arcsinh(z) = Log(z+sqrt(z^2+1)) is correct, we can verify this graphically.

> f:='f': z:='z':
f := z -> log(z + sqrt(z^2 + 1)):
`f(z) ` = f(z);
conformal(f(z), z=I*0.0001..10+I*10,
title=`w = log(z + sqrt(z^2 + 1))`,
grid=[11,11],numxy=[50,50],
scaling=constrained,
labels=[` u`,`v `],
view=[0..4,0..1.6]);

`f(z) ` = ln(z+sqrt(z^2+1))

[Maple Plot]

> `f(z) = arcsinh(z)`;
conformal(arcsinh(z), z = I*0.0001..10+I*10,
title=`w = arcsinh(z)`,
grid=[11,11], numxy=[50,50],
scaling=constrained,
labels=[` u`,`v `],
view=[0..4,0..1.6]);

`f(z) = arcsinh(z)`

[Maple Plot]

The Inverse Hyperbolic Cosine

Formula arccosh(z) = Log(z+sqrt(z^2-1)) is correct, we can verify this graphically.
But it is correct only in quadrants I and IV.

> f:='f': z:='z':
f := z -> log(z + sqrt(z^2 - 1)):
`f(z) ` = f(z);
conformal(f(z), z = I*0.0001..10+I*10,
title=`w = log(z + sqrt(z^2 - 1))`,
grid=[11,11], numxy=[50,50],
scaling=constrained,
labels=[` u`,`v `],
view=[0..4,0..1.6]);

`f(z) ` = ln(z+sqrt(z^2-1))

[Maple Plot]

> `f(z) = arccosh(z)`;
conformal(arccosh(z), z = I*0.0001..10+I*10,
title=`w = arccosh(z)`,
grid=[11,11], numxy=[50,50],
scaling=constrained,
labels=[` u`,`v `],
view=[0..4,0..1.6]);

`f(z) = arccosh(z)`

[Maple Plot]

REMARK. However, for other places it might not agree!
For Example in Quadrant II and III.
Here we must use the other branch of square root arccosh(z) = Log(z-sqrt(z^2-1)) .

> f:='f': z:='z':
f := z -> log(z - sqrt(z^2 - 1)):
`f(z) ` = f(z);
conformal(f(z), z = -10+I*0.0001..-0.0001+I*10,
title=`w = log(z - sqrt(z^2 - 1))`,
grid=[11,11], numxy=[50,50],
scaling=constrained,
labels=[` u`,`v `],
view=[0..4,0..3.2]);

`f(z) ` = ln(z-sqrt(z^2-1))

[Maple Plot]

> `f(z) = arccosh(z)`;
conformal(arccosh(z), z = -10+I*0.0001..-0.0001+I*10,
title=`w = arccosh(z)`,
grid=[11,11], numxy=[50,50],
scaling=constrained,
labels=[` u`,`v `],
view=[0..4,0..3.2]);

`f(z) = arccosh(z)`

[Maple Plot]

The Inverse Hyperbolic Tangent
Formula arctanh(z) = Log((1+z)/(1-z))/2 is correct, we can verify this graphically.

> f:='f': z:='z':
f := z -> 1/2 *log((1+z)/(1-z)):
`f(z) ` = f(z);
conformal(f(z), z = I*0.0001..10+I*10,
title=`w = 1/2 *log((1+z)/(1-z))`,
grid=[11,11], numxy=[50,50],
scaling=constrained,
labels=[`u`,`v `],
view=[0..1,0..1.6]);

`f(z) ` = 1/2*ln((1+z)/(1-z))

[Maple Plot]

> `f(z) = arctanh(z)`;
conformal(arctanh(z), z = I*0.0001..10+I*10,
title=`w = arctanh(z)`,
grid=[11,11], numxy=[50,50],
scaling=constrained,
labels=[`u`,`v `],
view=[0..1,0..1.6]);

`f(z) = arctanh(z)`

[Maple Plot]

>

End of Section 5.5.