Unit 1: Ordinary Differential Equations - Part 1

Chapter 5: Second-Order Differential Equations

Sections5.11: resonance

Copyright

Copyright * 2001 by Addison Wesley Longman, Inc.

All rights reserved. No part of this publication may be reproduced, stored in a retrieval system, or transmitted, in any form or by any means, electronic, mechanical, photocopying, recording, or otherwise, without the prior written permission of the publisher. Printed in the United States of America.

Initializations

> restart;

> with(plots):

Warning, the name changecoords has been redefined

>

Resonance

Resonance can be charcterized as that physical phenomenon whereby Mother Nature seems to over react to a lesser, but periodic, stimulus. This over reaction to a small stimulus is called a temper tantrum in a child, "having a fit" in an adult, and "resonance" in Mother Nature. The response is simply out of proportion to the stimulus.

Of course, we are just creating imagery to focus attention. However, anyone who has seen the four-minute film clip of the Tacoma Narrows Bridge, Tacoma, Washington, twisting in the wind and collapsing in 1940 would need no additional metaphors for resonance, the phenomenon responsible for such a ruinous end to a magnificent work of engineering.

Resonance is quantized within the driven damped oscillator. A linear, damped oscillator is driven with a sinusoidal input having a variable angular frequency. The response of the system is observed as a function of the driving input frequency. The frequency for which the response is greatest is called the resonant frequency , a frequency at which the magnitude of the system's response can be far larger than the magnitude of the input driving force.

We distinguish two cases of resonance. If damping is assumed to be zero, the system is a fiction, since even at supercooled temperatures, friction does not disappear entirely. The resonance model in which no damping term appears has characteristics that just cannot be found in nature since a frictionless system is just not found in nature. For this reason, this model is called "unreal resonance."

The more realistic model for resonance includes frictional damping, and is called "real resonance."

>

Unreal Resonance

The undamped undamped oscillator with mass and spring constant , driven by a periodic force of amplitude 1 and angular frequency , is modeled by the differential equation

that is, by

> q := diff(y(t),t,t) + 16*y(t) = cos(4*t);

>

If this system goes into motion with the inert initial conditions = 0, we can describe the resulting motions by the solution

> Y := rhs(dsolve({q, y(0) = 0, D(y)(0) = 0},y(t)));

>

graphed as the solid curve in the following figure (Figure 5.13).

> plot([t/8,-t/8,Y],t=0..10,color=[red,red,black], linestyle=[2,2,1]);

>

The oscillations of the system grow without bound, getting ever larger and larger. Of course, this is not what happens in reality where some frictional damping always exists. In this model with no damping, the envelope of the oscillations is linear, as shown by the dotted lines in Figure 5.13.

Fortunately, this unreal resonance is never seen in nature since nothing in nature takes place without frictional losses. But to see why the model predicts these unbounded motions, obtain the characteristic roots = + from the characteristic equation

The latent roots from the driving term are themselves + , so the particular solution will contain

Driving the system at its natural (angular) frequency means the trig terms in the particular solution are multiplied by . Physically, this correspondence means every imposed push lines up exactly with the natural peak in the motion, and the oscillations increase without bound.

Let us implement this investigation in Maple.

To begin, obtain the homogeneous and particular solutions from the general solution

> q2 := dsolve(q,y(t));

>

The particular solution survives when the arbitrary constants in the homogeneous solution are set equal to zero. Thus, the particular solution is

> yp := subs(_C1=0, _C2=0, rhs(q2));

>

The homogeneous solution contains the same term ( ) that is being used to drive the system. The driving angular frequency exactly matches the natural frequency as determined by the characteristic roots. The homogeneous solution captures the "natural" response of the system, the ocillatory motion whose (angular) frequency is 4. Driving the system at the same rate in the absence of damping means no energy is lost, and every push lines up exactly with the peak of the motion. Hence, the oscillations increase without bound.

The natural frequency of the undamped system is determined by the homogeneous equation

The characteristic equation is

so the with characteristic roots are

= +

These roots are complex, so the fundamental set will now be

Clearly, becomes the natural (angular) frequency since that is the frequency this system must necessarily exhibit if no external driving forces act on it. Driving the undamped system at its natural (angular) frequency causes it to resonate, a resonance that predicts unbounded motions.

However, in real life, there is always damping. Hence, we next consider the same system ( m = 1, k = 16) but add some damping to explore the case of real resonance. We will drive the system with a cosine term for which the frequency is not specified and seek to study the response of the system as a function of the driving frequency.

>

Real Resonance

Consider the damped oscillator for which the mass, damping, and spring constant are , and for which the driving term is . A model for this system is the differential equation

that is,

> q3 := diff(y(t),t,t) + 4*diff(y(t),t) + 16*y(t) = cos(omega*t);

>

with characteristic equation

and characteristic roots + . Since

is then a fundamental set, the natural (angular) frequency for the system is and the homogeneous solution is

We can obtain these results in Maple as follows. To obtain the homogeneous solution, we find the characteristic equation

> q4 := lambda^2 + 4*lambda + 16 = 0;

>

and its (characteristic) roots

> q5 := solve(q4, lambda);

>

Complex exponential solutions are

> q6 := exp(q5[1]*t);
q7 := exp(q5[2]*t);

>

and Euler's formulas let us write these complex exponentials as

> q8 := evalc(q6);
q9 := evalc(q7);

>

Taking linear combinations of these complex solutions yields other solutions that are real.

> y1 := (q8 + q9)/2;
y2 := (q8 - q9)/(2*I);

>

The homogeneous solution is then

> yh := collect(A*y1 + B*y2, exp(-2*t));

>

At steady-state when the term has done its work and effectively become zero, the homogeneous solution hardly contributes to the general solution. The steady-state solution is essentially the particular solution which we write in the form

> yp := A*cos(omega*t - phi);

>

The amplitude A and the phase angle are determined by the method of Undetermined Coefficients. Substituting into the differential equation yields

> q10 := eval(subs(y(t) = yp, q3));

>

This must be an identity in , so we seek values of the parameters and which will make this so. Thus, in Maple, we calculate

> q11 := solve(identity(expand(q10),t),{A,phi});

>

We are really only interested in the amplitude of the motion. We therefore extract just the positive value of .

> f := subs(q11[1],A);

>

and graph the amplitude function as a function of , obtaining Figure 5.14.

> plot(f, omega = 0..5);

>

For some value of the driving frequency , the magnitude of the steady-state's amplitude peaks. The driving frequency for which this amplitude is a maximum is called the resonant frequency which can be found exactly by solving the equation

Thus, in Maple we obtain

> q12 := solve(diff(f,omega),omega);

>

and the resonant frequency is

> omega[R] = q12[2];

>

The natural frequency of this system is found in the homogeneous solution:

> yh;

>

The natural frequency is , slightly larger than the resonant frequeny . For unreal (undamped) resonance, the natural frequency and the resonant frequency are the same. For real (damped) resonance the resonant frequency is slightly smaller than the natural frequency.

Steady-State Solution as a Function of

As a function of and , the particular solution is

which we obtain in Maple as follows.

The steady-state solution as a function of the driving frequency is simply . To obtain it, we first get the following expressions for and in terms of .

> C := simplify(subs(q11[1],cos(phi)));
S := simplify(subs(q11[1],sin(phi)));

>

Then, the particular solution in terms of is

> YP := subs(A=f, cos(phi)=C, sin(phi)=S, expand(yp));

>

The following figure, Figure 5.15, shows graph of three steady-state solutions for

= , and

as the red, black, and green curves, respectively. This figure therefore shows the variation in amplitude with .

> plot([subs(omega=3/2,YP), subs(omega=2*sqrt(2),YP), subs(omega=4,YP)], t=0..2*Pi, color=[red,black,green]);

>

The following animation is a more dynamic representation of the variation of amplitude with driving frequency.

> animate(YP,t=0..2*Pi, omega=0..6, frames=60, color=black);

>

Dependence of Resonance on Damping

It is important to quantify the resonant frequency's dependence on damping. Hence, let the damped oscillator above now have variable damping , so that the system is modeled by the differential equation

that is, by

> q13 := diff(y(t),t,t) + b*diff(y(t),t) + 16*y(t) = cos(omega*t);

>

As before, we want the system's steady-state response to the driving term, from which we extract the value of the driving frequency maximizing the amplitude of the response. Again taking the particular solution as

> yp;

>

the parameters A and are determined in Maple via the method of Undetermined Coefficients which starts with the substitution

> q14 := eval(subs(y(t) = yp, q13));

>

Since this must be an identity in , we use

> q15 := solve(identity(expand(q14),t),{A,phi});

>

to determine the appropriate parameters. Since we really want just the amplitude of the steady-state solution, we extract the positive value of A from the solution set in q15.

> f := subs(q15[1],A);

>

Again interested in how , the amplitude of the steady-state response, varies with driving frequency , we give the

damping coefficient the values ,

> for k from 1 to 5 do
f||k := subs(b = k, f);
od;

>

and plot the resulting resonance curves in the following figure, Figure 5.16.

> plot([f||(1..5)], omega=0..6, color = [red,blue,green,magenta,black]);

>

The red curve corresponds to . The more the damping, the smaller the maximum peak at resonance, and the less the damping, the greater the resonant peak. Also, if the damping is great enough there is no resonance peak at all. Hence, sufficient damping precludes resonance.

The following figure, Figure 5.17, is another way of looking at the dependence of the response amplitude on both damping and input driving frequency. The function is plotted as a surface over the -plane. The plane sections are the curves seen in Figure 5.16.

> plot3d(f, b = 1..5, omega = 0..6,axes=boxed, style=patchnogrid);

>

Both Figures 5.16 and 5.17 suggest that as the driving frequency is increased well past the resonant frequency, the amplitude of the steady-state response goes to zero.

Analytically, this is shown by the following limit.

> Limit(f, omega=infinity) = limit(f,omega=infinity);

>

Physically, this means that for high enough driving frequency, the system cannot react to the rapidity of the swings being imposed on it and the system becomes "paralysed." So if you have a motor shaking itself to pieces because of resonance, either add damping or increase the driving speed!

Finally, we obtain an expression for the resonant frequency as a function of the damping parameter . This expression is determined by solving the equation f '( ) = 0 for .

> q16 := solve(diff(f,omega) = 0, omega);

>

The resonant frequency is

> omega[R] = q16[2];

>

Formulae for the dependence of the resonant frequency on all three parameters of mass, damping, and spring constant are obtained below.

>

Dependence of Resonance on , and

Complete formulae for the dependence of the resonant frequency on mass, damping, and spring constant can be obtained by finding the steady-state (particular) solution of the differential equation

that is,

> k := 'k':

> q17:= m*diff(y(t),t,t) + b*diff(y(t),t) + k*y(t) = cos(omega*t);

>

Assuming the particular solution

> yp;

>

the differential equation yields

> q18 := eval(subs(y(t) = yp, q17));

>

from which the matching principle yields

> q19 := solve(identity(expand(q18),t),{A,phi});

>

The positive amplitude of this steady-state solution is given by

> f := subs(q19[1],A);

>

from which we obtain the maximizing value of by solving f '( ) = 0 for . Thus,

> q20 := solve(diff(f,omega) = 0, omega);

>

The resonant frequency is

> omega[R] = q20[2];

>

which can be written as

=

The first form for is more prevalent in texts, but the second makes it easier to see that is necessary for resonance.

>

Resonance Wrap-Up

Here are some questions about resonance, and oscillations in damped spring-mass systems. Answering them will help clarify the connections, formulas, and insights generated throughout this unit.

Questions

Can overdamped and critically damped systems be made to resonate?

Can every underdamped system be made to resonate?

What is the threshold of damping above which there can be no resonance?

What is the threshold of damping above which there are no transient oscillations?

>

Data

To answer these questions, we recall formulas for the natural frequency and the resonant frequency.

The quadratic formula for the characteristic roots of the characteristic equation gives the natural frequency:

+ =>

From , the discriminant of the characteristic equation, we can classify the motion as a function of damping:

The resonant frequency is

=

from which we draw the two inferences:

==> underdamped

==> resonance

The following plot (Figure 5.18) summarizes all this data on a - number line :

> p1 := plot([t,0,t=0..6],thickness=3, color=black):
p2 := plot({[[0,0],[0,1/2]],[[2,0],[2,1/2]],[[4,0],[4,1/2]]}, style=line, color=black,thickness=3):
p3 := plot({[[0,0],[0,-.5]],[[4,0],[4,-.5]]}, color=black,linestyle=2):
p4 := textplot({[0,.7,`0`],[2,.7,`2mk`],[4,.7,`4mk`]}, font=[TIMES,BOLD,14]):
p5 := textplot([6.3,0,`b`],font=[TIMES,BOLD,14]):
p6 := textplot([6.4,.2,`2`]):
p7 := textplot([2,-.3,`<----- underdamped ----->`], font=[TIMES,ROMAN,12]):
p8 := textplot([5.5,-.3,`<-- overdamped -->`], font=[TIMES,ROMAN,12]):
p9 := textplot({[4,-.7,`critically`],[4,-1,`damped`]}, font=[TIMES,ROMAN,12]):
p10 := textplot([1,.3,`resonance`], font=[TIMES,ROMAN,12]):
display([p||(1..10)],axes=none,scaling=constrained, title = `Figure 5.18`);

>

Answers

* Overdamped, critically damped, and "half" the underdamped systems cannot be made to resonate. In particular,

==> underdamped with resonance possible

==> underdamped but resonance not possible

We quote "half" because systems for which are all underdamped, but only those for which have a positive resonant frequency. In Figure 5.18 the underdamped systems for which resonance is possible appears to be "half" of the underdamped systems. Thus, the answer to the first question is "no, overdamped and critically damped systems cannot be made to resonate."

* The answer to the second question is "no, not every underdamped system can be made to resonate."

* The answer to the third question is " is the threshold above which a system cannot be made to resonate."

* And the answer to the last question is " is the threshold above which a system cannot be made to oscillate."

>

>