Module 2 : Geometry

204 : Centers Of A Triangle

What is the center of a triangle? Well there are at least four different answers :
the incenter is the center of the inscribed circle for a triangle
the circumcenter is the center of the circumscribed circle for a triangle
the centroid is the center of mass for a triangle.
the orthocenter is the center of the intersection of the altitudes
Its a fascinating fact that each of these centers is a point of concurrency of a triangle. Any two non-parallel lines will intersect. However, if you have three lines, it is highly unlikely they would happen to intersect at the same point. Such a point is a point of concurrency for the three lines. Each of the four points mentioned above is the intersection of three easily constructed lines for the triangle.

In this module, we will examine each of these points, and how they are defined, and see what they look like when plotted on a triangle. At the conclusion of this module you will better understand what each of the centers of a triangle is and how they are constructed.

___________________________________________________________________________________

A. Setup

___________________________________________________________________________________

We will begin by invoking the geometry spirits and defining some options which will save us typing later. If you return to this project at a later date, be sure to re-execute these definitions.

> with(geometry):

> fc := 'filled = true, color = coral':

> fbk := 'filled = true, color = black':

> cr := 'color = red, thickness = 2':

> cb := 'color = blue, thickness = 2':

> cg := 'color = green, thickness = 2':

> cw := 'color = white, thickness = 2':

We are going to define a single triangle and then do all kinds of things to it.

> point( A, [-3,-2]): point( B, [ 8, - 1]): point( C, [ 0,5]):

> triangle( T, [A,B,C]):

___________________________________________________________________________________

B. Angle Bisectors -> Incenter

___________________________________________________________________________________

A triangle has three angles. Each angle can be bisected by a line. The intersection of these three lines is the incenter, which is the center of the inscribed circle.

> bisector(bi1,A,T): bisector(bi2,B,T): bisector(bi3,C,T):

> draw( {T(fc), bi1,bi2,bi3});

Here is a veiw with the angle bisectors demonstrating they intersect the center of the inscribed circle.

> incircle( inT, T):

> draw( { inT(cr), center(inT) (cr), bi1, bi2, bi3, T(fc) });

___________________________________________________________________________________

C. Perpindicular Bisectors -> Circumcenter

___________________________________________________________________________________

A perpendicular bisector of a segment is another line which bisects the segment and at the same time is perpendicular to the segment. Each side of a triangle is a line segment, and therefore can be bisected. When all the perpendicular bisectors are drawn for all three sides, they intersect in a single point called the circumcenter which is the center of the circle which circumscribes the triangle.

> PerpenBisector( p1, A, B): PerpenBisector( p2, B, C): PerpenBisector( p3, A, C):

> draw( {T(fc), p1,p2,p3});

Here is a view with the angle bisectors demonstrating they intersect the center of the inscribed circle.

> circumcircle( outT, T):

> draw( {outT(cb), center(outT)(cb), p1, p2, p3, T(fc)} );

___________________________________________________________________________________

D. Medians -> Centroid

___________________________________________________________________________________

A median of a triangle is a line which connects a vertex with the midpoint of the opposite side. Note that a median, is usually not an angle bisector nor a perpendicular bisector, except in certain special cases. The point where the three medians meet is called the centroid. This is a very special point because it represents the center of gravity of the triangle. If the triangle were made out of metal or wood of even thickness, the centroid would be the only point where you could balance the triangle on the tip of a single finger!

> median(md1,A,T): median(md2,B,T): median(md3,C,T):

> draw( {T(fc), md1,md2,md3});

The centroid has another special property. It cuts each median into two pieces, one twice as long as the other. We can verify this. Note that the distance from the centroid to each vertex is exactly twice the distance from the centroid to midpoint.

> centroid( ct, T): midpoint( mAB, A, B): midpoint( mBC, B, C): midpoint( mAC, A, C):

> evalf( distance( C, ct)) ; evalf( distance( mAB, ct)) ;

> evalf( distance( A, ct)) ; evalf( distance( mBC, ct)) ;

> evalf( distance( B, ct)) ; evalf( distance( mAC, ct)) ;

___________________________________________________________________________________

E. Altitudes -> Orthocenter

___________________________________________________________________________________

An altitude is a line segment that extends from one vertex to the opposite side, or an extension of that opposite side, and is perpendicular to it. An altitude is somewhat like a median in that it goes from vertex to opposite side, however, it does not necessarily pass through the midpoint of the opposite side. Many times, the altitude is located outside of the circle. The intersection of the three altitudes is called the orthocenter.

> altitude(alt1,A,T): altitude(alt2,B,T): altitude(alt3,C,T):

> draw( {T(fc), alt1,alt2, alt3 });

___________________________________________________________________________________

F. All Together Row

___________________________________________________________________________________

We've seen all four points of concurrency. How do they look together? Lets draw all 12 of the lines discussed on a single diagram.

> draw( { p1(cb),p2(cb),p3(cb), bi1(cr),bi2(cr),bi3(cr),
md1(cg), md2(cg), md3(cg), alt1(cw), alt2(cw), alt3(cw), T(fbk) });

The blue lines are the perpindicular bisectors and their point of intersection the incenter. The red lines are the angle bisectors and their intersection is the circum- center. The green lines are the medians and their intersection is the centroid. And the white lines are the altitudes with their intersection being the orthocenter.

Thats a bit too much. Lets just look at the incenter and circumcenter and their circles.

> incircle( inT, T): circumcircle( outT, T):

> draw( { inT(cr), outT(cb), center(inT) (cr), center(outT) (cb), T(fc) });

Now lets look at all four points of concurrency without the clutter of the 12 the line segments.

> centroid( ct, T); orthocenter( oc, T);

> draw( {inT(cr), outT(cb), center(inT)(cr), center(outT)(cb), T(fc), ct(cg), oc(fbk)});

>

>