Module 6 : Precalculus

602 : Operations with Complex Numbers

O B J E C T I V E

In this project we will examine at complex numbers from both an algebraic and geometric point of view. We will look at where the come from, how to define them in Maple, how to perform mathematical operations, and what these operations mean geometrically.

S E T U P

In this project we will use the following command packages. Type and execute this line before begining the project below. If you re-enter the worksheet for this project, be sure to re-execute this statement before jumping to any point in the worksheet.

> restart; with(plots):

Warning, the name changecoords has been redefined

___________________________________________________________________________________

A. The Sum and Difference Of Complex Numbers

___________________________________________________________________________________

Its easy to add complex numbers in Maple

> z := -4 + I; w := 1 + 3*I;

> z+w;

> complexplot( {z,w,z+w }, x = -6..6,
style = point);

>

Complex numbers are added geometrically using the parallelogram rule.

The blue line shows the position of z, the green line shows the position of w. The yellow lines complete the parallelogram. The diagonal of the parallelogram indicates the position of z+w.

> display( complexplot( { 0, z }, x = -6..6,
color=blue, thickness = 2),
complexplot( { 0, w }, x = -6..6,
color=green, thickness = 2),
complexplot( { z,z+w}, x = -6..6,
color=yellow),
complexplot( {w, z+w },x = -6..6,
color=yellow),
complexplot( {0, z+w },x = -6..6,
color=red, thickness = 3) );

You can also compute the difference of two complex numbers

> z := 4 + I; w := 1 + 3*I;

> z+w, z-w, w-z;

> display( complexplot( {z,w}, x = -6..6, style = point, color=blue),
complexplot( {-z,-w}, x = -6..6, style = point, color=red),
complexplot( {z+w}, x = -6..6, style = point, color=green),
complexplot( {z-w, w-z }, x = -6..6, style = point, color=black) );

Both z and w are blue. Their negatives are red. Their sum is green, and their differences are black. You can see which difference is which by thinking of z -w as z + (-w), w - z as (-z) + w, and using the parellelogram rule.

___________________________________________________________________________________

B. The Product Of Complex Numbers

___________________________________________________________________________________

The product of two complex numbers can be easily computed also

> z := 2 + I; w := -1 + 3*I;

> z*w;

> display( complexplot( { 0,z}, x = -6..6, color=blue ),
complexplot( { 0,w}, x = 0..6, color=green ),
complexplot( { 0,z*w }, x = 0..5, color=red) );

The red line is the product of z and w.

How is the product zw related to z and w geometrically?

The modulus of the product is the product of the moduli.

> abs(z), abs(w), abs(z)*abs(w), abs(z*w);

The argument of the product is the sum of the arguments (sometimes plus or minus a multiple of 2), somewhat like a logarithm.

> angle_z:= evalf( argument(z));

> angle_w := evalf( argument(w));

> angle_zw := evalf(argument(z*w));

> angle_z + angle_w;

___________________________________________________________________________________

C. Powers of Complex Numbers

___________________________________________________________________________________

Taking a power of a complex number is repeated multiplication. For numbers with modulus 1, the results are other points on the unit circle.

> z := cos(Pi/7) + sin(Pi/7)*I; a := abs(z);

> display( complexplot( {0,z}, x = -1..1, color=blue,scaling=constrained ),
seq( complexplot( { 0, z^k }, x = -1..1, color=green ), k = 2..11 ) );

For numbers with modulus less than one, each multiplication by z creates a number closer to the origin.

> z := .8 + .35*I; a := abs(z);

> display(complexplot( z, x = -1..1, color=blue, style = point, scaling = constrained ),
complexplot( { z^k $ k = 2..18 }, x = -1..1, color=green, style = point ) ,
polarplot( a, scaling=constrained, color = gold) );

Looking at a number of powers of z at once, the numbers seem to spiral inward toward the origin.

For numbers with modulus greater than one, the powers spiral away from the unit circle

> z := .8 + .9*I;

> a := abs(z);

> display( complexplot( { 0,z}, x = -1..1, color=blue),
polarplot( 1,scaling=constrained, color = gold),
seq(complexplot({z^(k-1), z^k },x= -8..8, color=green ),k =2..11));

___________________________________________________________________________________

D. Complex Roots of Unity

___________________________________________________________________________________

Only numbers that have an absolute value (modulus) of 1, lie on the unit circle. Conversely, any root of 1 must also lie on the unit circle. In fact, such roots are spaced evenly around the unit circle with the first one being the real number 1.

We need to return z to being an unknown, since we defined it to have various values above.

> z := 'z';

Lets solve the equation

Note that we get three answers because the equation is degree 3.

> solve( z^3 = 1);

Each of these numbers, when cubed, yields 1.

> z1 := (-1 + I*sqrt(3))/2;

> z1^3;

> evalc(z1^3);

Lets look at all 12 roots of unity.

> n := 12;

> roots_of_unity := solve( z^n = 1, z);

> display( complexplot( {roots_of_unity[k] $ k = 1..n}, x = -1..1,
style = point, color = blue),
polarplot(1,scaling = constrained, color = gold ));

>