Module 6 : Precalculus

603 : Exponential Functions

O B J E C T I V E

In the project we will investigate exponential functions, exponential growth and decay, and problems involving these things along with other exponential functions.

S E T U P

In this project we will use the following command packages. Type and execute this line before begining the project below. If you re-enter the worksheet for this project, be sure to re-execute this statement before jumping to any point in the worksheet.

> restart; with(plots):

Warning, the name changecoords has been redefined

___________________________________________________________________________________

A. Growth & Decay

___________________________________________________________________________________

First, well just catch a glimpse of what exponential growth and decay looks like. Here is a family of exponential functions with the same growth rate, but differing initial values ( C = 10, 20 , 30, ..., 100).

> plot( { 10*k*exp(x/5) $ k = 1..10}, x = -4..4, y = 0..250,
title=`Exponential Growth - Different Initial Values`);

Here is a family of exponential functions with the same initial value (C), but differing growth rates (1/5, 2/5, 3/5,...,2). Note that all of these functions are increasing.

> plot( { 10*exp(x*k/5) $ k = 1..10}, x = 0..4, y = 0..100,
title=`Exponential Growth - Different Growth Rates`);

This family has differing decay rates. Note that these functions area all decreasing.

> plot( { 10*exp(-x*k/5) $ k = 1..10}, x = 0..10,
title=`Exponential Decay - Different Decay Rates`);

In this single diagram we can see both growing (increasing) and decaying (decreasing) exponential functions.

> plots[display]( plot( { 100*exp(x*k/200) $ k = 1..10}, x = -20..20, color = green,
title= `Red = Decay and Green = Growth , `),
plot( { 100*exp(-x*k/200) $ k = 1..10}, x = -20..20, color = red));

___________________________________________________________________________________

B. Solving Exponential Problems

___________________________________________________________________________________

Now well solve exponential growth and decay problems analytically.

PROBLEM 1

PROBLEM : A population begins with 1,200 at time t = 0, and grows exponentially, until it reaches 3,500 at time t = 9.
A. Fiind a simplified function which expresses the size of the population at time t.
B. What is the size at t = 36?
C. At what time does the population reach 100,000?

> restart; f := t -> C*exp(k*t);

> 1200 = f(0); solve(%, { C } ); assign( % ); f(t);

> 3500 = f(9); solve( %, { k }); assign( % ); simplify( f(t), exp);

> f(36); evalf(%);

> solve( 100000 = f(t)); evalf(%);

PROBLEM 2

PROBLEM : A population begins with 2,500 at time t = 2, and grows exponentially, until it reaches 6,000 at time t = 7.
A. Fiind a simplified function which expresses the size of the population at time t.
B. What is the size at t = 12 and t = 20?

> restart;

> f := t -> C*exp(k*t);

> solve( f(2) = 2500, {C} ); assign(%); f(t);

> solve( f(7) = 6000, {k} ); assign(%); simplify( f(t), exp );

> f(12); f(20); evalf(%);

PROBLEM 3

PROBLEM : A population begins with 35,000 at time t = 0, and grows exponentially at 6% per year.
A. Fiind a simplified function which expresses the size of the population at time t.
B. What is the size at t = 8?

> restart;

> f := t -> C*exp(k*t);

> solve( f(0) = 35000, {C} ); assign(%); f(t);

> f(1) = 1.06*f(0); solve( %, {k}); assign(%);

> f(t);

> f(8);

PROBLEM 4

PROBLEM : A population begins with 432,000 at time t = 0, and grows exponentially, until it reaches 511,000 at time t = 3. Fiind the annual growth rate.

FIND ANNUAL GROWTH RATE

> restart; f := t -> C*exp(k*t);

> f(0) = 432000; solve( %, {C}); assign(%); f(t);

> f(3) = 511000; solve( %, {k}); assign(%); f(t);

> simplify(%, exp);

> (% - 1)*100;

> evalf( f(1)/f(0) );

PROBLEM 5

PROBLEM : Using Newtons law of cooling, an object brought into a room of T0 degrees will have this temperature at time t : T(t) = T0 + Cekt. If the object is 48 degrees is brought into a room of 32 degrees, and is 42 degrees at time t = 10 :
A. Find a simplified formula for the temperature of this object at time t
B. Find at what time the object will reach 35 degrees.
C. Find the temperature at t = 200.
D. Plot the graph of this function.

> restart;

> T := t -> T0 + C*exp(k*t);

> T0 := 32; T(t);

> T(0) = 48; solve(%, {C}); assign(%); T(t);

> T(10) = 42; solve(%, {k}); assign(%); simplify(T(t), exp);

> solve( T(x) = 35, x); evalf(%);

> T(200); evalf(%);

> plot( {T(x), T0}, x = 0..20, y = 0..(T0+C));

___________________________________________________________________________________

C. Half Life

___________________________________________________________________________________

One particular type of exponential decay problem involves the half-life of a radioactive material. The half life is the time period for half of the material to decay.

The half-life is the solution to the equation :
f(t) = .5*f(0).

> restart;

> f := t -> N*.85^(t);

> HL := solve( f(t) = (1/2)*f(0), t);

We can view the effect of the half-life in this example of an exponential decay function.

> with(plots):
N := 100;

Warning, the name changecoords has been redefined

> display(plot( {100, seq( [[HL*2^(k-1) ,0],[HL*2^(k-1), f(0)]] , k = 1..5),
seq( [[0 ,f(HL*2^(k-1))],[N, f(HL*2^(k-1))]] , k = 1..5)}, x = 0..N, color = green),
plot( f(x), x = 0..N, title=`half-life`, color = blue) );

Note that each vertical line is half as high the previous, and each horizontal line is twice as large.

___________________________________________________________________________________

D. Other Exponential Functions

___________________________________________________________________________________

Here are some examples of some other exponential type functions.

SURGE FUNCTION

> f := (x,a,b) -> a*x*exp(-b*x);

> plot( f(x, 1, .1), x = 0..100);

> plot( { f(x, k, .1) $ k = 1..20 }, x = 0..100, color = khaki);

> plot( { f(x, 1, k/50) $ k = 1..20 }, x = 0..100, color = khaki);

LOGISTIC GROWTH

> plot( exp(x)/(1+exp(x)), x = -8..8);

> plot( {exp(x*(.5*k))/(1 + exp(x*k)) $ k = 1..16}, x = -1..1, color =khaki);

OTHER FAMILIES OF EXPONENTIAL FUNCTIONS

A.

> plot( {exp(x*k)/(1 + exp(k*x)) $ k = 1..20}, x = -5..5, color = khaki);

B.

> plot( {exp(x*k)/(1 + k*exp(x*k)) $ k = 1..16}, x = -3..3, color = khaki);

C.

> plot( {1 - exp(x*k)/(1 + exp(x*k)) $ k = 1..20}, x = -2..2, color = green);

D.

> plot( {exp(x*(.5*k))/(1 + k*exp(x*k)) $ k = 1..16}, x = -1..1, color = khaki);

E.

> plot( {exp(x*(.01*k))/(1 + (k)*exp(x*k)) $ k = 1..20}, x = -3..3, color = khaki);

>

F.

> plot( {exp(x*(.9*k))/(1 + sqrt(k)*exp(x*k)) $ k = 1..20}, x =-3..3);

G.

> plot( {1+k*exp(x*(.9*k))/(1 + sqrt(k)*exp(x*k)) $ k = 1..20},x=-3..3);

H.

> plot( {1+ (k^2)*exp(x*(.95*k))/(1 + sqrt(k)*exp(x*k)) $ k = 1..20},x = -3..3);