0. Code

>	restart; with(plots):

Warning, the name changecoords has been redefined

>	IdentityPlot  :=  proc( Identity ) local c1,c2; c1 := COLOR(RGB, .5,.5, .7); c2 := COLOR(RGB, .3,.3, .4); plot( [lhs(Identity ), rhs(Identity )+.06],          x = 0..2*Pi, y = -3..3, discont = true,          thickness = 3, color = [c1,c2], numpoints = 100 ); end proc:

 1. Visualizing Identities

Although it is not a valid method of verifying an identity, we can convince ourselves that an identity is true by graphing the left and right sides of the identity as separate graphs. If they are the same, then this will reassure us.

>	(tan(x) - sec(x))*(sin(x) + 1)  = -cos(x);

>	IdentityPlot(   %);

>	sin(2*x) + sin(2*x) = 4*sin(x)*cos(x); IdentityPlot(   %);

>	tan(x) + cot(x) = 1/(sin(x)*cos(x)) ; IdentityPlot(   %);

Although a graph won't prove any identity, it can easily show when an identity is false.

>	sin(2*x) * cos(2*x) = 4*sin(x)*cos(x) ; IdentityPlot(   %);

>	sin(2*x) + sin(2*x) = 4*sin(x); IdentityPlot(   %);

>	tan(x) + cot(x) = 2*sin(x)*cos(x) ; IdentityPlot(   %);

>	sin(x) +  sin(2*x) = sin(3*x); IdentityPlot(   %);

 2. Testing Identities Numerically

As before, this method does not prove any identity, but it helps to convince us of the validity - an inspiration that can lead to a proof of the validity.

         Example  :  

>	Id1 :=        (tan(x) - sec(x))*(sin(x) + 1)  = -cos(x);

>	array( [[ k*Pi/12,  evalf(subs( x =k*Pi/12,lhs(Id1)),3),                     evalf(subs( x =k*Pi/12,rhs(Id1)),3)]         $ k= 1..5] );

This method is valid for proving that a false identity is false.

>	Id1 :=        sin(2*x) + sin(2*x)  = sin(4*x); array( [[ k*Pi/12, subs( x =k*Pi/12,lhs(Id1)), subs( x =k*Pi/12,rhs(Id1))]         $ k= 1..12] );

 3.  Proving Identities Algebraically

The normal way of verifying an identity is to simplify one side or the other (or both) to show that the two expressions are equivalent. It's quite similar to simplifying an equation. Basically, each side at each step is always equivalent to the original equation.

       Example  3.1:  

One way of solving an identity, although not always the most elegant way, is to simply convert everything to sines and cosines.

>	Id1 :=        (tan(x) - sec(x))*(sin(x) + 1)  = -cos(x);

>	subs( {tan(x) = sin(x)/cos(x), sec(x) = 1/cos(x)}, lhs(Id1));

>	simplify(%, trig);

Thus the left side has been reduced to be the same as the right side. Thus we are done.

We can also use this command to do these substitutions more automatically.

>	convert( Id1, 'sincos' ); simplify(%, trig);

The left side has been reduced to be the same as the right side. Thus we are done...again.

      Example  3.2 :     

>	Id1 :=        tan(x) + cot(x) = 1/(sin(x)*cos(x)) ;

>	subs( {tan(x) = sin(x)/cos(x), cot(x) = cos(x)/sin(x)}, lhs(Id1));

>	normal(%);

>	simplify(%, trig);

This is the same as the original right side.